Процедура ТоварыНоменклатураОкончаниеВводаТекста(Элемент, Текст, ДанныеВыбора, СтандартнаяОбработка)

    СтандартнаяОбработка = Ложь;

    ТекущаяСтрока = Элементы.Товары.ТекущиеДанные;

    Если НЕ ПустаяСтрока(Текст) Тогда
        Список = НайтиНоменклатуру(Текст);
        ДанныеВыбора = Новый СписокЗначений;
        Для Каждого ТекЗначение Из Список Цикл
            ДанныеВыбора.Добавить(ТекЗначение.Значение);
        КонецЦикла;
    КонецЕсли;

КонецПроцедуры

Список = НайтиНоменклатуру(Текст); - вот эта строка очень долго выполняется. Можете подсказать почему?

вызывается эта функция

&НаСервере
Функция НайтиНоменклатуру(Текст)

    Запрос = Новый Запрос;
    Запрос.Текст = "ВЫБРАТЬ РАЗРЕШЕННЫЕ
                    |    Номенклатура.Ссылка
                    |ИЗ
                    |    Справочник.Номенклатура КАК Номенклатура
                    |ГДЕ
                    |    Номенклатура.Код ПОДОБНО &Код";

    Запрос.УстановитьПараметр("Код", "%"+Текст+"%");

    Результат = Запрос.Выполнить();

    ВыборкаДетальныеЗаписи = Результат.Выбрать();

    Список = Новый СписокЗначений;
    Пока ВыборкаДетальныеЗаписи.Следующий() Цикл
        Список.Добавить(ВыборкаДетальныеЗаписи.Ссылка);
    КонецЦикла;

    Возврат Список;

КонецФункции

(0) Смотри что это за функция.

сама функция быстро выполняется

Ленится

Потому что ПОДОБНО. Перебор всей номенклатуры.

(5) а чем можно заменить?

Потому что поиск идет по вхождению в любую часть кода, т.е. полный перебор всей номенклатуры.

и еще, можно упростить:
Возврат Результат.Выбрать().Выгрузить().ВыгрузитьКолонку("Ссылка")

Статистику на сервере обнови

(8) * выбрать() убрать кнечно же

И индексы пересчитай

(6) Используй еще.


&НаСервереБезКонтекста
Функция НайтиНоменклатуру(Знач Текст)

Я бы, для начала, условие поставил:
Если СтрДлина(Текст)>=3 Тогда

(0) &НаСервереБезКонтекста

(13) +1

Если долго возврат на клиента происходит, то наверное очень много значений, ограничь список 20 где- нибудь, т.е. выбрать первые 20

(0) ВЫБРАТЬ  ПЕРВЫЕ 50
Посмотри как в типовых сделано

(0)По коду

Результат = Запрос.Выполнить();
ТЗ = Результат.Выгрузить();
Массив = ТЗ.ВыгрузитьКолонку("Ссылка");
Список = Новый СписокЗначений;
Список.ЗагрузитьЗначения(Массив);
Возврат Список;

Убрать код:
        Список = НайтиНоменклатуру(Текст);
        ДанныеВыбора = Новый СписокЗначений;
        Для Каждого ТекЗначение Из Список Цикл
            ДанныеВыбора.Добавить(ТекЗначение.Значение);
        КонецЦикла;

Оставить:
        ДанныеВыбора = НайтиНоменклатуру(Текст);

(0) А так, тебя ждет еще разочарование. Список будет выпадать еще через менеджер справочника, к которому ты обращаешься "Номенклатура"

сам по себе вызов сервера дело весьма небыстрое.

(20) Через "НаСервереБезКонтекста" и не будет летать твоя форма туда обратно.

+ Если еще и переменные функции уложишь в "Знач", то и они не будут возвращаться обратно на клиент

(22) +

Всем большое спасибо, особенно Зомби, быстрее стало работать