Как сделать?
Добавил доп.реквизит в характеристику, назвал "Уценка", тип булево.
Проставляется, все ок.
Хочу, чтобы в основной сегмент не попадал, т.к. на уценку не должна распространяться скидка.
Но в отборе сегмента можно указывать доп.реквизиты номенклатуры, но нельзя доп.реквизиты характеристики...

Как сделать?

Сегмент / Настройки / Редактировать схему компоновки
у поля Характеристика снять флажки "Недоступно как условие" (Условие)

(0) ба, какие люди

(1) да, но этого мало.
не хотелось редактировать схему, но по другому никак.
Надо еще прописать и запрос на характеристики.

В итоге весь запрос выглядит так:


ВЫБРАТЬ
    Номенклатура.Ссылка КАК ЭлементСписка,
    ЕСТЬNULL(ХарактеристикиНоменклатуры.Ссылка, ЗНАЧЕНИЕ(Справочник.ХарактеристикиНоменклатуры.ПустаяСсылка)) КАК ХарактеристикаЭлемента
ИЗ
    Справочник.Номенклатура КАК Номенклатура
        ЛЕВОЕ СОЕДИНЕНИЕ Справочник.ХарактеристикиНоменклатуры КАК ХарактеристикиНоменклатуры
        ПО (ХарактеристикиНоменклатуры.Владелец = Номенклатура.Ссылка)

ОБЪЕДИНИТЬ ВСЕ

ВЫБРАТЬ
    Номенклатура.Ссылка,
    ЕСТЬNULL(ХарактеристикиНоменклатуры.Ссылка, ЗНАЧЕНИЕ(Справочник.ХарактеристикиНоменклатуры.ПустаяСсылка))
ИЗ
    Справочник.Номенклатура КАК Номенклатура
        ЛЕВОЕ СОЕДИНЕНИЕ Справочник.ХарактеристикиНоменклатуры КАК ХарактеристикиНоменклатуры
        ПО (ХарактеристикиНоменклатуры.Владелец = Номенклатура.ВидНоменклатуры)

Вот этот кусок добавлен, обратите внимание на префикс РЕЗ, без него совпадает с ключевым словом и не работает.

{ХАРАКТЕРИСТИКИ
    ТИП(Справочник.ХарактеристикиНоменклатуры)
    ВИДЫХАРАКТЕРИСТИК ПланВидовХарактеристик.ДополнительныеРеквизитыИСведения
    ПОЛЕКЛЮЧА Ссылка
    ПОЛЕИМЕНИ Заголовок
    ПОЛЕТИПАЗНАЧЕНИЯ ТипЗначения
    ЗНАЧЕНИЯХАРАКТЕРИСТИК (ВЫБРАТЬ
            ХарактеристикиНоменклатурыДополнительныеРеквизиты.Ссылка КАК Ссылка,
            ХарактеристикиНоменклатурыДополнительныеРеквизиты.Свойство КАК РезСвойство,
            ХарактеристикиНоменклатурыДополнительныеРеквизиты.Значение КАК РезЗначение
        ИЗ
            Справочник.ХарактеристикиНоменклатуры.ДополнительныеРеквизиты КАК ХарактеристикиНоменклатурыДополнительныеРеквизиты)
    ПОЛЕОБЪЕКТА Ссылка
    ПОЛЕВИДА РезСвойство
    ПОЛЕЗНАЧЕНИЯ РезЗначение }



И условия надо добавлять через группу ИЛИ:
ИЛИ:
- Характеристика.Уценка не заполнена
- Характеристика.Уценка не равно Да

уценка на новую характеристику?
или нет ситуации, когда есть товар по характеристики и хорошего качества и уценка?