HTTPЗапрос = Новый HTTPЗапрос("/v4/sheets/",+ Парам, Заголовки);
может есть у кого готовая строчка кода для заполнения переменной "Парам" ?
нужно передать айди таблицы и свойства создаваемого листа. знаю свойства и айди таблицы, но не знаю синтаксис.
(авторизация по OAuth 2.0 )

(0) Запятой перед "+" нету. очепятка

100500 примеров на инфостарте

(2) по созданию листа?

может пригодится кому
<code>
Функция СоздатьЛист(IdТаблицы,НовыйAccess)    
    ТаймаутСоединения =30;
    Host = "sheets.googleapis.com";
    SSL = Новый ЗащищенноеСоединениеOpenSSL(Неопределено, Неопределено);        
    Соединение = Новый HTTPСоединение(Host, , , , ,ТаймаутСоединения,SSL);
    Заголовки = Новый Соответствие;
    Заголовки.Вставить("Authorization", "Bearer " + НовыйAccess);
    ЗаписьJSON = Новый ЗаписьJSON;
    ЗаписьJSON.УстановитьСтроку();    
    Данные = Новый Структура;
    Данные.Вставить("requests", Новый Массив);    
    ДанныеТК = Новый Структура("red, green, blue", 1, 1, 1);
    ДанныеГП = Новый Структура("rowCount, columnCount", 20, 12);
    ДанныеСв = Новый Структура("title, gridProperties, tabColor", "МоёИмя", ДанныеГП, ДанныеТК);    
    ДанныеПР = Новый Структура("properties", ДанныеСв);    
    ДанныеАШ = Новый Структура("addSheet", ДанныеПР);    
    Данные.requests.Добавить(ДанныеАШ);
    ЗаписатьJSON(ЗаписьJSON, Данные);
    Буквы = ЗаписьJSON.Закрыть();
    HTTPЗапрос = Новый HTTPЗапрос("/v4/spreadsheets/"+IdТаблицы+":batchUpdate", Заголовки);
    HTTPЗапрос.УстановитьТелоИзСтроки(Буквы);
    HTTPОтвет = Соединение.ВызватьHTTPМетод("POST",HTTPЗапрос);
    СтрокаОтвет = HTTPОтвет.ПолучитьТелоКакСтроку();
    Возврат СтрокаОтвет;
КонецФункции

</code>